Thanks to Batronyx (Barrett) for his code to make
single image stereograms with POV.

Here is a single image stereogram of the classic POV-Ray
sample scene Skyvase.pov. This one is made for cross-eye
viewing.I've included the modified skyvase.pov scene for making
the depthmap.


Haroldd

-- skyvase depthmap ---


global_settings { assumed_gamma 2.2 max_trace_level 20 }

#include "shapes.inc"
#include "shapes2.inc"
#include "colors.inc"
#include "textures.inc"

#declare DMF_Hyperboloid = quadric {  /* Like Hyperboloid_Y, but more curvy
*/
   <1.0, -1.0,  1.0>,
   <0.0,  0.0,  0.0>,
   <0.0,  0.0,  0.0>,
   -0.5
}

// camera repositioned to approximate a scene based on one unit depth

camera {
   location <0.0, -0.15, -1.0>
   look_at <0.0, -0.15, 0.0>
   angle 80
}

// No lights, only z gradient.

// Place entire original skyvase scene into a union
// remove original textures

union{
 union {
   union {
      intersection {
         plane { y, 0.7 }
         object { DMF_Hyperboloid scale <0.75, 1.25, 0.75> }
         object { DMF_Hyperboloid scale <0.70, 1.25, 0.70> inverse }
         plane { y, -1.0 inverse }
      }
      sphere { <0, 0, 0>, 1 scale <1.6, 0.75, 1.6 > translate <0, -1.15,
0> }
      scale <20, 25, 20>
   }

   sphere {  /* Gold ridge around sphere portion of vase*/
      <0, 0, 0>, 1
      scale <1.6, 0.75, 1.6>
      translate -7*y
      scale <20.5, 4.0, 20.5>
    }
 }

/* Stand for the vase */
 object { Hexagon
   rotate -90.0*z             /* Stand it on end (vertical)*/
   rotate -45*y               /* Turn it to a pleasing angle */
   scale <40, 25, 40>
   translate -70*y
 }

 union {
   plane { z, 50  rotate -45*y }
   plane { z, 50  rotate +45*y }
   hollow on
   }

// Scale the scene to be close to one unit depth, from closest object to
rear.

    scale 0.01

// ** Add texture gradient **


    texture {pigment {gradient z
// Remove next line to reverse depth map for cross-eye SIS
//     color_map{[0.0 White][1.0 Black]}
     }
// adjust size and position of gradient textue to create optimal placement
// of light area (at the begining of the front object, the stand).
       finish {ambient 1 diffuse 0}
       scale 1.16 translate z*1.866}
   }

Post a reply to this message

Attachments:
Download 'skyvaseSISx.jpg' (128 KB)

Preview of image 'skyvaseSISx.jpg'